Using just with Django#

Jeff Triplett convinced me to take a look at just as a command automation tool - sort of an alternative to Make, except with a focus on commands rather than managing build dependencies.

I really like it, and I’ve started using it for my own Django projects.

Installing with Homebrew#

Installing just on my Mac was easy:

1
brew install just

The tool is written in Rust and provides binaries for basically everything - there are plenty more ways to install it.

Writing a Justfile#

The Justfile defines which commands just makes available. When you run just it looks for a Justfile in the current or any parent directory.

Commands in that file are run as if the working directory was the directory containing the Justfile.

Here’s the file I’ve built so far for my current Django project. The project already uses pipenv and has some slightly convoluted environment requirements - just is a perfect tool for patching over those so I don’t have to think about them any more.

I added some comments to help explain what’s going on:

1
# Using export here causes this DATABASE_URL to be made available as an
2
# environment variable for any command run by Just
3
export DATABASE_URL := "postgresql://localhost/myproject"
4

5
# The first command is the default if you run "just" with no options.
6
# I used *options to allow this to accept options, which means I can run:
7
#
8
#    just test -k auth --pdb
9
#
10
# To pass the "-k auth --pdb" options to pytest
11

12
@test *options:
13
  pipenv run pytest {{options}}
14

15
# This starts the Django development server with an extra environment variable
16
# I also print out a URL to the console so I can click on it without
17
# remembering which extra item I configured in /etc/hosts for this project
18
@server:
19
  echo "Starting http://myapp.local:8000/"
20
  DJANGO_SETTINGS_MODULE="config.localhost" pipenv run ./manage.py runserver
21

22
# I added this so I could run things like "just manage migrate" to run migrations
23
@manage *options:
24
  DJANGO_SETTINGS_MODULE="config.localhost" pipenv run ./manage.py {{options}}

The @ before a command name causes that command to NOT output each line to the console before it is executed, which I found is usually what I wanted.

Here’s what that example looks like without the comments: it’s pretty succinct.

1
export DATABASE_URL := "postgresql://localhost/myproject"
2

3
@test *options:
4
  pipenv run pytest {{options}}
5

6
@server:
7
  echo "Starting http://myapp.local:8000/"
8
  DJANGO_SETTINGS_MODULE="config.localhost" pipenv run ./manage.py runserver
9

10
@manage *options:
11
  DJANGO_SETTINGS_MODULE="config.localhost" pipenv run ./manage.py {{options}}

What this lets me do#

To list all options:

1
% just --list
2
Available recipes:
3
    manage *options
4
    server
5
    test *options

To run all of my tests:

1
just

To run specific tests

1
just test -k name

To run tests, stopping at the first error and opening a debugger:

1
just test -x --pdb

To start my development server running:

1
just server

To run migrations:

1
just manage migrate

To run ./manage.py shell:

1
just manage shell

More examples#

I found Jeff’s scripts-to-rule-them-all example really helpful in learning how to use just.

The official README is excellent.